62. Classical Filtering With Linear Algebra #

Contents

Classical Filtering With Linear Algebra

62.1. Overview #

This is a sequel to the earlier lecture Classical Control with Linear Algebra.

That lecture used linear algebra – in particular, the LU decomposition – to formulate and solve a class of linear-quadratic optimal control problems.

In this lecture, we’ll be using a closely related decomposition, the Cholesky decomposition , to solve linear prediction and filtering problems.

We exploit the useful fact that there is an intimate connection between two superficially different classes of problems:

deterministic linear-quadratic (LQ) optimal control problems
linear least squares prediction and filtering problems

The first class of problems involves no randomness, while the second is all about randomness.

Nevertheless, essentially the same mathematics solves both type of problem.

This connection, which is often termed “duality,” is present whether one uses “classical” or “recursive” solution procedures.

In fact we saw duality at work earlier when we formulated control and prediction problems recursively in lectures LQ dynamic programming problems, A first look at the Kalman filter, and The permanent income model.

A useful consequence of duality is that

With every LQ control problem there is implicitly affiliated a linear least squares prediction or filtering problem.
With every linear least squares prediction or filtering problem there is implicitly affiliated a LQ control problem.

An understanding of these connections has repeatedly proved useful in cracking interesting applied problems.

For example, Sargent [Sar87] [chs. IX, XIV] and Hansen and Sargent [HS80] formulated and solved control and filtering problems using $z$ -transform methods.

In this lecture we investigate these ideas using mostly elementary linear algebra.

62.1.1. References#

Useful references include [Whi63], [HS80], [Orf88], [AP91], and [Mut60].

62.2. Infinite Horizon Prediction and Filtering Problems #

We pose two related prediction and filtering problems.

We let $Y_{t}$ be a univariate $m^{t h}$ order moving average, covariance stationary stochastic process,

(62.1)#

Y_{t} = d (L) u_{t}

where $d (L) = \sum_{j = 0}^{m} d_{j} L^{j}$ , and $u_{t}$ is a serially uncorrelated stationary random process satisfying

(62.2)#

\begin{array}{r} \begin{aligned} E u_{t} & = 0 \\ E u_{t} u_{s} & = {\begin{cases} 1 & if t = s \\ 0 & otherwise \end{cases} \end{aligned} \end{array}

We impose no conditions on the zeros of $d (z)$ .

A second covariance stationary process is $X_{t}$ given by

(62.3)#

X_{t} = Y_{t} + ε_{t}

where $ε_{t}$ is a serially uncorrelated stationary random process with $E ε_{t} = 0$ and $E ε_{t} ε_{s}$ = $0$ for all distinct $t$ and $s$ .

We also assume that $E ε_{t} u_{s} = 0$ for all $t$ and $s$ .

The linear least squares prediction problem is to find the $L_{2}$ random variable ${\hat{X}}_{t + j}$ among linear combinations of ${X_{t}, X_{t - 1}, \dots}$ that minimizes $E ({\hat{X}}_{t + j} - X_{t + j})^{2}$ .

That is, the problem is to find a $γ_{j} (L) = \sum_{k = 0}^{\infty} γ_{j k} L^{k}$ such that $\sum_{k = 0}^{\infty} | γ_{j k} |^{2} < \infty$ and $E [γ_{j} (L) X_{t} - X_{t + j}]^{2}$ is minimized.

The linear least squares filtering problem is to find a $b (L) = \sum_{j = 0}^{\infty} b_{j} L^{j}$ such that $\sum_{j = 0}^{\infty} | b_{j} |^{2} < \infty$ and $E [b (L) X_{t} - Y_{t}]^{2}$ is minimized.

Interesting versions of these problems related to the permanent income theory were studied by [Mut60].

62.2.1. Problem formulation#

These problems are solved as follows.

The covariograms of $Y$ and $X$ and their cross covariogram are, respectively,

(62.4)#

\begin{array}{r} \begin{aligned} C_{X} (τ) & = E X_{t} X_{t - τ} \\ C_{Y} (τ) & = E Y_{t} Y_{t - τ} τ = 0, \pm 1, \pm 2, \dots \\ C_{Y, X} (τ) & = E Y_{t} X_{t - τ} \end{aligned} \end{array}

The covariance and cross covariance generating functions are defined as

(62.5)#

\begin{array}{r} \begin{aligned} g_{X} (z) & = \sum_{τ = - \infty}^{\infty} C_{X} (τ) z^{τ} \\ g_{Y} (z) & = \sum_{τ = - \infty}^{\infty} C_{Y} (τ) z^{τ} \\ g_{Y X} (z) & = \sum_{τ = - \infty}^{\infty} C_{Y X} (τ) z^{τ} \end{aligned} \end{array}

The generating functions can be computed by using the following facts.

Let $v_{1 t}$ and $v_{2 t}$ be two mutually and serially uncorrelated white noises with unit variances.

That is, $E v_{1 t}^{2} = E v_{2 t}^{2} = 1, E v_{1 t} = E v_{2 t} = 0, E v_{1 t} v_{2 s} = 0$ for all $t$ and $s$ , $E v_{1 t} v_{1 t - j} = E v_{2 t} v_{2 t - j} = 0$ for all $j \neq 0$ .

Let $x_{t}$ and $y_{t}$ be two random process given by

\begin{array}{r} \begin{aligned} y_{t} & = A (L) v_{1 t} + B (L) v_{2 t} \\ x_{t} & = C (L) v_{1 t} + D (L) v_{2 t} \end{aligned} \end{array}

Then, as shown for example in [Sar87] [ch. XI], it is true that

(62.6)#

\begin{array}{r} \begin{aligned} g_{y} (z) & = A (z) A (z^{- 1}) + B (z) B (z^{- 1}) \\ g_{x} (z) & = C (z) C (z^{- 1}) + D (z) D (z^{- 1}) \\ g_{y x} (z) & = A (z) C (z^{- 1}) + B (z) D (z^{- 1}) \end{aligned} \end{array}

Applying these formulas to (62.1) – (62.4), we have

(62.7)#

\begin{array}{r} \begin{aligned} g_{Y} (z) & = d (z) d (z^{- 1}) \\ g_{X} (z) & = d (z) d (z^{- 1}) + h \\ g_{Y X} (z) & = d (z) d (z^{- 1}) \end{aligned} \end{array}

The key step in obtaining solutions to our problems is to factor the covariance generating function $g_{X} (z)$ of $X$ .

The solutions of our problems are given by formulas due to Wiener and Kolmogorov.

These formulas utilize the Wold moving average representation of the $X_{t}$ process,

(62.8)#

X_{t} = c (L) η_{t}

where $c (L) = \sum_{j = 0}^{m} c_{j} L^{j}$ , with

(62.9)#

c_{0} η_{t} = X_{t} - \hat{E} [X_{t} | X_{t - 1}, X_{t - 2}, \dots]

Here $\hat{E}$ is the linear least squares projection operator.

Equation (62.9) is the condition that $c_{0} η_{t}$ can be the one-step ahead error in predicting $X_{t}$ from its own past values.

Condition (62.9) requires that $η_{t}$ lie in the closed linear space spanned by $[X_{t}, X_{t - 1}, \dots]$ .

This will be true if and only if the zeros of $c (z)$ do not lie inside the unit circle.

It is an implication of (62.9) that $η_{t}$ is a serially uncorrelated random process, and that a normalization can be imposed so that $E η_{t}^{2} = 1$ .

Consequently, an implication of (62.8) is that the covariance generating function of $X_{t}$ can be expressed as

(62.10)#

g_{X} (z) = c (z) c (z^{- 1})

It remains to discuss how $c (L)$ is to be computed.

Combining (62.6) and (62.10) gives

(62.11)#

d (z) d (z^{- 1}) + h = c (z) c (z^{- 1})

Therefore, we have already showed constructively how to factor the covariance generating function $g_{X} (z) = d (z) d (z^{- 1}) + h$ .

We now introduce the annihilation operator:

(62.12)#

{[\sum_{j = - \infty}^{\infty} f_{j} L^{j}]}_{+} \equiv \sum_{j = 0}^{\infty} f_{j} L^{j}

In words, $[]_{+}$ means “ignore negative powers of $L$ ”.

We have defined the solution of the prediction problem as $\hat{E} [X_{t + j} | X_{t}, X_{t - 1}, \dots] = γ_{j} (L) X_{t}$ .

Assuming that the roots of $c (z) = 0$ all lie outside the unit circle, the Wiener-Kolmogorov formula for $γ_{j} (L)$ holds:

(62.13)#

γ_{j} (L) = {[\frac{c (L)}{L^{j}}]}_{+} c (L)^{- 1}

We have defined the solution of the filtering problem as $\hat{E} [Y_{t} ∣ X_{t}, X_{t - 1}, \dots] = b (L) X_{t}$ .

The Wiener-Kolomogorov formula for $b (L)$ is

b (L) = {(\frac{g_{Y X} (L)}{c (L^{- 1})})}_{+} c (L)^{- 1}

(62.14)#

b (L) = {[\frac{d (L) d (L^{- 1})}{c (L^{- 1})}]}_{+} c (L)^{- 1}

Formulas (62.13) and (62.14) are discussed in detail in [Whi83] and [Sar87].

The interested reader can there find several examples of the use of these formulas in economics Some classic examples using these formulas are due to [Mut60].

As an example of the usefulness of formula (62.14), we let $X_{t}$ be a stochastic process with Wold moving average representation

X_{t} = c (L) η_{t}

where $E η_{t}^{2} = 1, and c_{0} η_{t} = X_{t} - \hat{E} [X_{t} | X_{t - 1}, \dots], c (L) = \sum_{j = 0}^{m} c_{j} L$ .

Suppose that at time $t$ , we wish to predict a geometric sum of future $X$ ’s, namely

y_{t} \equiv \sum_{j = 0}^{\infty} δ^{j} X_{t + j} = \frac{1}{1 - δ L^{- 1}} X_{t}

given knowledge of $X_{t}, X_{t - 1}, \dots$ .

We shall use (62.14) to obtain the answer.

Using the standard formulas (62.6), we have that

\begin{array}{r} \begin{aligned} g_{y x} (z) & = (1 - δ z^{- 1}) c (z) c (z^{- 1}) \\ g_{x} (z) & = c (z) c (z^{- 1}) \end{aligned} \end{array}

Then (62.14) becomes

(62.15)#

b (L) = {[\frac{c (L)}{1 - δ L^{- 1}}]}_{+} c (L)^{- 1}

In order to evaluate the term in the annihilation operator, we use the following result from [HS80].

Proposition Let

$g (z) = \sum_{j = 0}^{\infty} g_{j} z^{j}$ where $\sum_{j = 0}^{\infty} | g_{j} |^{2} < + \infty$
$h (z^{- 1}) =$ $(1 - δ_{1} z^{- 1}) \dots (1 - δ_{n} z^{- 1})$ , where $| δ_{j} | < 1$ , for $j = 1, \dots, n$

Then

(62.16)#

{[\frac{g (z)}{h (z^{- 1})}]}_{+} = \frac{g (z)}{h (z^{- 1})} - \sum_{j = 1}^{n} \frac{δ_{j} g (δ_{j})}{\prod_{\binom{k = 1}{k \neq j}}^{n} (δ_{j} - δ_{k})} (\frac{1}{z - δ_{j}})

and, alternatively,

(62.17)#

{[\frac{g (z)}{h (z^{- 1})}]}_{+} = \sum_{j = 1}^{n} B_{j} (\frac{z g (z) - δ_{j} g (δ_{j})}{z - δ_{j}})

where $B_{j} = 1 / \prod_{\binom{k = 1}{k + j}}^{n} (1 - δ_{k} / δ_{j})$ .

Applying formula (62.17) of the proposition to evaluating (62.15) with $g (z) = c (z)$ and $h (z^{- 1}) = 1 - δ z^{- 1}$ gives

b (L) = [\frac{L c (L) - δ c (δ)}{L - δ}] c (L)^{- 1}

b (L) = [\frac{1 - δ c (δ) L^{- 1} c (L)^{- 1}}{1 - δ L^{- 1}}]

Thus, we have

(62.18)#

\hat{E} [\sum_{j = 0}^{\infty} δ^{j} X_{t + j} | X_{t}, x_{t - 1}, \dots] = [\frac{1 - δ c (δ) L^{- 1} c (L)^{- 1}}{1 - δ L^{- 1}}] X_{t}

This formula is useful in solving stochastic versions of problem 1 of lecture Classical Control with Linear Algebra in which the randomness emerges because ${a_{t}}$ is a stochastic process.

The problem is to maximize

(62.19)#

E_{0} lim_{N \to \infty} \sum_{t - 0}^{N} β^{t} [a_{t} y_{t} - \frac{1}{2} h y_{t}^{2} - \frac{1}{2} [d (L) y_{t}]^{2}]

where $E_{t}$ is mathematical expectation conditioned on information known at $t$ , and where ${a_{t}}$ is a covariance stationary stochastic process with Wold moving average representation

a_{t} = c (L) η_{t}

where

c (L) = \sum_{j = 0}^{\tilde{n}} c_{j} L^{j}

and

η_{t} = a_{t} - \hat{E} [a_{t} | a_{t - 1}, \dots]

The problem is to maximize (62.19) with respect to a contingency plan expressing $y_{t}$ as a function of information known at $t$ , which is assumed to be $(y_{t - 1}, y_{t - 2}, \dots, a_{t}, a_{t - 1}, \dots)$ .

The solution of this problem can be achieved in two steps.

First, ignoring the uncertainty, we can solve the problem assuming that ${a_{t}}$ is a known sequence.

The solution is, from above,

c (L) y_{t} = c (β L^{- 1})^{- 1} a_{t}

(62.20)#

(1 - λ_{1} L) \dots (1 - λ_{m} L) y_{t} = \sum_{j = 1}^{m} A_{j} \sum_{k = 0}^{\infty} (λ_{j} β)^{k} a_{t + k}

Second, the solution of the problem under uncertainty is obtained by replacing the terms on the right-hand side of the above expressions with their linear least squares predictors.

Using (62.18) and (62.20), we have the following solution

(1 - λ_{1} L) \dots (1 - λ_{m} L) y_{t} = \sum_{j = 1}^{m} A_{j} [\frac{1 - β λ_{j} c (β λ_{j}) L^{- 1} c (L)^{- 1}}{1 - β λ_{j} L^{- 1}}] a_{t}

62.3. Finite Dimensional Prediction #

Let $(x_{1}, x_{2}, \dots, x_{T})^{'} = x$ be a $T \times 1$ vector of random variables with mean $E x = 0$ and covariance matrix $E x x^{'} = V$ .

Here $V$ is a $T \times T$ positive definite matrix.

We shall regard the random variables as being ordered in time, so that $x_{t}$ is thought of as the value of some economic variable at time $t$ .

For example, $x_{t}$ could be generated by the random process described by the Wold representation presented in equation (62.8).

In this case, $V_{i j}$ is given by the coefficient on $z^{∣ i - j ∣}$ in the expansion of $g_{x} (z) = d (z) d (z^{- 1}) + h$ , which equals $h + \sum_{k = 0}^{\infty} d_{k} d_{k + ∣ i - j ∣}$ .

We shall be interested in constructing $j$ step ahead linear least squares predictors of the form

\hat{E} [x_{T} | x_{T - j}, x_{T - j + 1}, \dots, x_{1}]

where $\hat{E}$ is the linear least squares projection operator.

The solution of this problem can be exhibited by first constructing an orthonormal basis of random variables $ε$ for $x$ .

Since $V$ is a positive definite and symmetric, we know that there exists a (Cholesky) decomposition of $V$ such that

V = L^{- 1} (L^{- 1})^{'}

L V L^{'} = I

where $L$ is lower-trangular, and therefore so is $L^{- 1}$ .

Form the random variable $L x = ε$ .

Then $ε$ is an orthonormal basis for $x$ , since $L$ is nonsingular, and $E ε ε^{'} = L E x x^{'} L^{'} = I$ .

It is convenient to write out the equations $L x = ε$ and $L^{- 1} ε = x$

(62.21)#

\begin{array}{r} \begin{aligned} L_{11} x_{1} & = ε_{1} \\ L_{21} x_{1} + L_{22} x_{2} & = ε_{2} \\ ⋮ \\ L_{T 1} x_{1} \dots + L_{T T x_{T}} & = ε_{T} \end{aligned} \end{array}

(62.22)#

\sum_{j = 0}^{t - 1} L_{t, t - j} x_{t - j} = ε_{t}, t = 1, 2, \dots T

We also have

(62.23)#

x_{t} = \sum_{j = 0}^{t - 1} L_{t, t - j}^{- 1} ε_{t - j} .

Notice from (62.23) that $x_{t}$ is in the space spanned by $ε_{t}, ε_{t - 1}, \dots, ε_{1}$ , and from (62.22) that $ε_{t}$ is in the space spanned by $x_{t}, x_{t - 1}, \dots, x_{1}$ .

Therefore, we have that for $t - 1 \geq m \geq 1$

(62.24)#

\hat{E} [x_{t} ∣ x_{t - m}, x_{t - m - 1}, \dots, x_{1}] = \hat{E} [x_{t} ∣ ε_{t - m}, ε_{t - m - 1}, \dots, ε_{1}]

For $t - 1 \geq m \geq 1$ rewrite (62.23) as

(62.25)#

x_{t} = \sum_{j = 0}^{m - 1} L_{t, t - j}^{- 1} ε_{t - j} + \sum_{j = m}^{t - 1} L_{t, t - j}^{- 1} ε_{t - j}

Representation (62.25) is an orthogonal decomposition of $x_{t}$ into a part $\sum_{j = m}^{t - 1} L_{t, t - j}^{- 1} ε_{t - j}$ that lies in the space spanned by $[x_{t - m}, x_{t - m + 1}, \dots, x_{1}]$ , and an orthogonal component not in this space.

62.3.1. Implementation#

Code that computes solutions to LQ control and filtering problems using the methods described here and in Classical Control with Linear Algebra can be found in the file control_and_filter.jl.

Here’s how it looks

using LinearAlgebra, Statistics
using Polynomials.PolyCompat, LinearAlgebra
import Polynomials.PolyCompat: roots, coeffs

function LQFilter(d, h, y_m;
                  r = nothing,
                  beta = nothing,
                  h_eps = nothing)
    m = length(d) - 1
    m == length(y_m) ||
        throw(ArgumentError("y_m and d must be of same length = $m"))

    # define the coefficients of phi up front
    phi = zeros(2m + 1)
    for i in (-m):m
        phi[m - i + 1] = sum(diag(d * d', -i))
    end
    phi[m + 1] = phi[m + 1] + h

    # if r is given calculate the vector phi_r
    if isnothing(r)
        k = nothing
        phi_r = nothing
    else
        k = size(r, 1) - 1
        phi_r = zeros(2k + 1)

        for i in (-k):k
            phi_r[k - i + 1] = sum(diag(r * r', -i))
        end

        if isnothing(h_eps) == false
            phi_r[k + 1] = phi_r[k + 1] + h_eps
        end
    end

    # if beta is given, define the transformed variables
    if isnothing(beta)
        beta = 1.0
    else
        d = beta .^ (collect(0:m) / 2) * d
        y_m = y_m * beta .^ (-collect(1:m) / 2)
    end

    return (; d, h, y_m, m, phi, beta, phi_r, k)
end

function construct_W_and_Wm(lqf, N)
    (; d, m) = lqf

    W = zeros(N + 1, N + 1)
    W_m = zeros(N + 1, m)

    # terminal conditions
    D_m1 = zeros(m + 1, m + 1)
    M = zeros(m + 1, m)

    # (1) constuct the D_{m+1} matrix using the formula

    for j in 1:(m + 1)
        for k in j:(m + 1)
            D_m1[j, k] = dot(d[1:j, 1], d[(k - j + 1):k, 1])
        end
    end

    # Make the matrix symmetric
    D_m1 = D_m1 + D_m1' - Diagonal(diag(D_m1))

    # (2) Construct the M matrix using the entries of D_m1

    for j in 1:m
        for i in (j + 1):(m + 1)
            M[i, j] = D_m1[i - j, m + 1]
        end
    end
    M

    # Euler equations for t = 0, 1, ..., N-(m+1)
    phi, h = lqf.phi, lqf.h

    W[1:(m + 1), 1:(m + 1)] = D_m1 + h * I
    W[1:(m + 1), (m + 2):(2m + 1)] = M

    for (i, row) in enumerate((m + 2):(N + 1 - m))
        W[row, (i + 1):(2m + 1 + i)] = phi'
    end

    for i in 1:m
        W[N - m + i + 1, (end - (2m + 1 - i) + 1):end] = phi[1:(end - i)]
    end

    for i in 1:m
        W_m[N - i + 2, 1:((m - i) + 1)] = phi[(m + 1 + i):end]
    end

    return W, W_m
end

function roots_of_characteristic(lqf)
    (; m, phi) = lqf

    # Calculate the roots of the 2m-polynomial
    phi_poly = Poly(phi[end:-1:1])
    proots = roots(phi_poly)
    # sort the roots according to their length (in descending order)
    roots_sorted = sort(proots, by = abs)[end:-1:1]
    z_0 = sum(phi) / polyval(poly(proots), 1.0)
    z_1_to_m = roots_sorted[1:m]     # we need only those outside the unit circle
    lambda = 1 ./ z_1_to_m
    return z_1_to_m, z_0, lambda
end

function coeffs_of_c(lqf)
    (; m) = lqf
    z_1_to_m, z_0, lambda = roots_of_characteristic(lqf)
    c_0 = (z_0 * prod(z_1_to_m) * (-1.0)^m)^(0.5)
    c_coeffs = coeffs(poly(z_1_to_m)) * z_0 / c_0
    return c_coeffs
end

function solution(lqf)
    z_1_to_m, z_0, lambda = roots_of_characteristic(lqf)
    c_0 = coeffs_of_c(lqf)[end]
    A = zeros(m)
    for j in 1:m
        denom = 1 - lambda / lambda[j]
        A[j] = c_0^(-2) / prod(denom[1:m .!= j])
    end
    return lambda, A
end

function construct_V(lqf; N = nothing)
    if isnothing(N)
        error("N must be provided!!")
    end
    if !(N isa Integer)
        throw(ArgumentError("N must be Integer!"))
    end

    (; phi_r, k) = lqf
    V = zeros(N, N)
    for i in 1:N
        for j in 1:N
            if abs(i - j) <= k
                V[i, j] = phi_r[k + abs(i - j) + 1]
            end
        end
    end
    return V
end

function simulate_a(lqf, N)
    V = construct_V(N + 1)
    d = MVNSampler(zeros(N + 1), V)
    return rand(d)
end

function predict(lqf, a_hist, t)
    N = length(a_hist) - 1
    V = construct_V(N + 1)

    aux_matrix = zeros(N + 1, N + 1)
    aux_matrix[1:(t + 1), 1:(t + 1)] = Matrix(I, t + 1, t + 1)
    L = cholesky(V).U'
    Ea_hist = inv(L) * aux_matrix * L * a_hist

    return Ea_hist
end

function optimal_y(lqf, a_hist, t = nothing)
    (; beta, y_m, m) = lqf

    N = length(a_hist) - 1
    W, W_m = construct_W_and_Wm(lqf, N)

    F = lu(W, Val(true))

    L, U = F
    D = diagm(0 => 1.0 ./ diag(U))
    U = D * U
    L = L * diagm(0 => 1.0 ./ diag(D))

    J = reverse(Matrix(I, N + 1, N + 1), dims = 2)

    if isnothing(t)                      # if the problem is deterministic
        a_hist = J * a_hist

        # transform the a sequence if beta is given
        if beta != 1
            a_hist = reshape(a_hist * (beta^(collect(N:0) / 2)), N + 1, 1)
        end

        a_bar = a_hist - W_m * y_m        # a_bar from the lecutre
        Uy = \(L, a_bar)                  # U @ y_bar = L^{-1}a_bar from the lecture
        y_bar = \(U, Uy)                  # y_bar = U^{-1}L^{-1}a_bar
        # Reverse the order of y_bar with the matrix J
        J = reverse(Matrix(I, N + m + 1, N + m + 1), dims = 2)
        y_hist = J * vcat(y_bar, y_m)     # y_hist : concatenated y_m and y_bar
        # transform the optimal sequence back if beta is given
        if beta != 1
            y_hist = y_hist .* beta .^ (-collect((-m):N) / 2)
        end

    else                                  # if the problem is stochastic and we look at it
        Ea_hist = reshape(predict(a_hist, t), N + 1, 1)
        Ea_hist = J * Ea_hist

        a_bar = Ea_hist - W_m * y_m       # a_bar from the lecutre
        Uy = \(L, a_bar)                  # U @ y_bar = L^{-1}a_bar from the lecture
        y_bar = \(U, Uy)                  # y_bar = U^{-1}L^{-1}a_bar

        # Reverse the order of y_bar with the matrix J
        J = reverse(Matrix(I, N + m + 1, N + m + 1), dims = 2)
        y_hist = J * vcat(y_bar, y_m)     # y_hist : concatenated y_m and y_bar
    end
    return y_hist, L, U, y_bar
end

optimal_y (generic function with 2 methods)

Let’s use this code to tackle two interesting examples.

62.3.2. Example 1#

Consider a stochastic process with moving average representation

x_{t} = (1 - 2 L) ε_{t}

where $ε_{t}$ is a serially uncorrelated random process with mean zero and variance unity.

We want to use the Wiener-Kolmogorov formula (62.13) to compute the linear least squares forecasts $E [x_{t + j} ∣ x_{t}, x_{t - 1}, \dots]$ , for $j = 1, 2$ .

We can do everything we want by setting $d = r$ , generating an instance of LQFilter, then invoking pertinent methods of LQFilter

m = 1
y_m = zeros(m)
d = [1.0, -2.0]
r = [1.0, -2.0]
h = 0.0
example = LQFilter(d, h, y_m, r = d)

(d = [1.0, -2.0], h = 0.0, y_m = [0.0], m = 1, phi = [-2.0, 5.0, -2.0], beta = 1.0, phi_r = [-2.0, 5.0, -2.0], k = 1)

The Wold representation is computed by example.coefficients_of_c().

Let’s check that it “flips roots” as required

coeffs_of_c(example)

2-element Vector{Float64}:
  2.0
 -1.0

roots_of_characteristic(example)

([2.0], -2.0, [0.5])

Now let’s form the covariance matrix of a time series vector of length $N$ and put it in $V$ .

Then we’ll take a Cholesky decomposition of $V = L^{- 1} L^{- 1} = L i L i^{'}$ and use it to form the vector of “moving average representations” $x = L i ε$ and the vector of “autoregressive representations” $L x = ε$

V = construct_V(example, N = 5)

5×5 Matrix{Float64}:
  5.0  -2.0   0.0   0.0   0.0
 -2.0   5.0  -2.0   0.0   0.0
  0.0  -2.0   5.0  -2.0   0.0
  0.0   0.0  -2.0   5.0  -2.0
  0.0   0.0   0.0  -2.0   5.0

Notice how the lower rows of the “moving average representations” are converging to the appropriate infinite history Wold representation

F = cholesky(V)
Li = F.L

5×5 LowerTriangular{Float64, Matrix{Float64}}:
  2.23607     ⋅         ⋅         ⋅         ⋅ 
 -0.894427   2.04939    ⋅         ⋅         ⋅ 
  0.0       -0.9759    2.01187    ⋅         ⋅ 
  0.0        0.0      -0.9941    2.00294    ⋅ 
  0.0        0.0       0.0      -0.998533  2.00073

Notice how the lower rows of the “autoregressive representations” are converging to the appropriate infinite history autoregressive representation

L = inv(Li)

5×5 LowerTriangular{Float64, Matrix{Float64}}:
 0.447214    ⋅          ⋅         ⋅         ⋅ 
 0.19518    0.48795     ⋅         ⋅         ⋅ 
 0.0946762  0.236691   0.49705    ⋅         ⋅ 
 0.0469898  0.117474   0.246696  0.499266   ⋅ 
 0.0234518  0.0586295  0.123122  0.249176  0.499817

Remark Let $π (z) = \sum_{j = 0}^{m} π_{j} z^{j}$ and let $z_{1}, \dots, z_{k}$ be the zeros of $π (z)$ that are inside the unit circle, $k < m$ .

Then define

θ (z) = π (z) (\frac{(z_{1} z - 1)}{(z - z_{1})}) (\frac{(z_{2} z - 1)}{(z - z_{2})}) \dots (\frac{(z_{k} z - 1)}{(z - z_{k})})

The term multiplying $π (z)$ is termed a “Blaschke factor”.

Then it can be proved directly that

θ (z^{- 1}) θ (z) = π (z^{- 1}) π (z)

and that the zeros of $θ (z)$ are not inside the unit circle.

62.3.3. Example 2#

Consider a stochastic process $X_{t}$ with moving average representation

X_{t} = (1 - \sqrt{2} L^{2}) ε_{t}

where $ε_{t}$ is a serially uncorrelated random process with mean zero and variance unity.

Let’s find a Wold moving average representation for $x_{t}$ .

Let’s use the Wiener-Kolomogorov formula (62.13) to compute the linear least squares forecasts $\hat{E} [X_{t + j} ∣ X_{t - 1}, \dots] for j = 1, 2, 3$ .

We proceed in the same way as example 1

m = 2
y_m = [0.0, 0.0]
d = [1, 0, -sqrt(2)]
r = [1, 0, -sqrt(2)]
h = 0.0
example = LQFilter(d, h, y_m, r = d)

(d = [1.0, 0.0, -1.4142135623730951], h = 0.0, y_m = [0.0, 0.0], m = 2, phi = [-1.4142135623730951, 0.0, 3.0000000000000004, 0.0, -1.4142135623730951], beta = 1.0, phi_r = [-1.4142135623730951, 0.0, 3.0000000000000004, 0.0, -1.4142135623730951], k = 2)

coeffs_of_c(example)

3-element Vector{Float64}:
  1.4142135623731025
 -0.0
 -1.0000000000000078

roots_of_characteristic(example)

([1.1892071150027195, -1.1892071150027195], -1.4142135623731136, [0.8408964152537157, -0.8408964152537157])

V = construct_V(example, N = 8)

8×8 Matrix{Float64}:
  3.0       0.0      -1.41421   0.0      …   0.0       0.0       0.0
  0.0       3.0       0.0      -1.41421      0.0       0.0       0.0
 -1.41421   0.0       3.0       0.0          0.0       0.0       0.0
  0.0      -1.41421   0.0       3.0         -1.41421   0.0       0.0
  0.0       0.0      -1.41421   0.0          0.0      -1.41421   0.0
  0.0       0.0       0.0      -1.41421  …   3.0       0.0      -1.41421
  0.0       0.0       0.0       0.0          0.0       3.0       0.0
  0.0       0.0       0.0       0.0         -1.41421   0.0       3.0

F = cholesky(V)
Li = F.L
Li[(end - 2):end, :]

3×8 Matrix{Float64}:
 0.0  0.0  0.0  -0.92582   0.0        1.46385   0.0      0.0
 0.0  0.0  0.0   0.0      -0.966092   0.0       1.43759  0.0
 0.0  0.0  0.0   0.0       0.0       -0.966092  0.0      1.43759

L = inv(Li)

8×8 LowerTriangular{Float64, Matrix{Float64}}:
 0.57735    ⋅         ⋅         ⋅        …   ⋅         ⋅         ⋅ 
 0.0       0.57735    ⋅         ⋅            ⋅         ⋅         ⋅ 
 0.308607  0.0       0.654654   ⋅            ⋅         ⋅         ⋅ 
 0.0       0.308607  0.0       0.654654      ⋅         ⋅         ⋅ 
 0.19518   0.0       0.414039  0.0           ⋅         ⋅         ⋅ 
 0.0       0.19518   0.0       0.414039  …  0.68313    ⋅         ⋅ 
 0.131165  0.0       0.278243  0.0          0.0       0.695608   ⋅ 
 0.0       0.131165  0.0       0.278243     0.459078  0.0       0.695608

62.3.4. Prediction#

It immediately follows from the “orthogonality principle” of least squares (see [AP91] or [Sar87] [ch. X]) that

(62.26)#

\begin{array}{r} \begin{aligned} \hat{E} & [x_{t} ∣ x_{t - m}, x_{t - m + 1}, \dots x_{1}] = \sum_{j = m}^{t - 1} L_{t, t - j}^{- 1} ε_{t - j} \\ = [L_{t, 1}^{- 1} L_{t, 2}^{- 1}, \dots, L_{t, t - m}^{- 1} 0 0 \dots 0] L x \end{aligned} \end{array}

This can be interpreted as a finite-dimensional version of the Wiener-Kolmogorov $m$ -step ahead prediction formula.

We can use (62.26) to represent the linear least squares projection of the vector $x$ conditioned on the first $s$ observations $[x_{s}, x_{s - 1} \dots, x_{1}]$ .

We have

(62.27)#

\begin{array}{r} \hat{E} [x ∣ x_{s}, x_{s - 1}, \dots, x_{1}] = L^{- 1} [\begin{array}{c} I_{s} & 0 \\ 0 & 0_{(t - s)} \end{array}] L x \end{array}

This formula will be convenient in representing the solution of control problems under uncertainty.

Equation (62.23) can be recognized as a finite dimensional version of a moving average representation.

Equation (62.22) can be viewed as a finite dimension version of an autoregressive representation.

Notice that even if the $x_{t}$ process is covariance stationary, so that $V$ is such that $V_{i j}$ depends only on $| i - j |$ , the coefficients in the moving average representation are time-dependent, there being a different moving average for each $t$ .

If $x_{t}$ is a covariance stationary process, the last row of $L^{- 1}$ converges to the coefficients in the Wold moving average representation for ${x_{t}}$ as $T \to \infty$ .

Further, if $x_{t}$ is covariance stationary, for fixed $k$ and $j > 0, L_{T, T - j}^{- 1}$ converges to $L_{T - k, T - k - j}^{- 1}$ as $T \to \infty$ .

That is, the “bottom” rows of $L^{- 1}$ converge to each other and to the Wold moving average coefficients as $T \to \infty$ .

This last observation gives one simple and widely-used practical way of forming a finite $T$ approximation to a Wold moving average representation.

First, form the covariance matrix $E x x^{'} = V$ , then obtain the Cholesky decomposition $L^{- 1} L^{- 1^{'}}$ of $V$ , which can be accomplished quickly on a computer.

The last row of $L^{- 1}$ gives the approximate Wold moving average coefficients.

This method can readily be generalized to multivariate systems.

62.4. Combined Finite Dimensional Control and Prediction #

Consider the finite-dimensional control problem, maximize

E \sum_{t = 0}^{N} {a_{t} y_{t} - \frac{1}{2} h y_{t}^{2} - \frac{1}{2} [d (L) y_{t}]^{2}}, h > 0

where $d (L) = d_{0} + d_{1} L + \dots + d_{m} L^{m}$ , $L$ is the lag operator, $\bar{a} = [a_{N}, a_{N - 1} \dots, a_{1}, a_{0}]^{'}$ a random vector with mean zero and $E \bar{a} {\bar{a}}^{'} = V$ .

The variables $y_{- 1}, \dots, y_{- m}$ are given.

Maximization is over choices of $y_{0}, y_{1} \dots, y_{N}$ , where $y_{t}$ is required to be a linear function of ${y_{t - s - 1}, t + m - 1 \geq 0; a_{t - s}, t \geq s \geq 0}$ .

We saw in the lecture Classical Control with Linear Algebra that the solution of this problem under certainty could be represented in feedback-feedforward form

\begin{array}{r} U \bar{y} = L^{- 1} \bar{a} + K [\begin{array}{c} y_{- 1} \\ ⋮ \\ y_{- m} \end{array}] \end{array}

for some $(N + 1) \times m$ matrix $K$ .

Using a version of formula (62.26), we can express $\hat{E} [\bar{a} ∣ a_{s}, a_{s - 1}, \dots, a_{0}]$ as

\begin{array}{r} \hat{E} [\bar{a} ∣ a_{s}, a_{s - 1}, \dots, a_{0}] = {\tilde{U}}^{- 1} [\begin{array}{c} 0 & 0 \\ 0 & I_{(s + 1)} \end{array}] \tilde{U} \bar{a} \end{array}

where $I_{(s + 1)}$ is the $(s + 1) \times (s + 1)$ identity matrix, and $V = {\tilde{U}}^{- 1} {\tilde{U}}^{- 1^{'}}$ , where $\tilde{U}$ is the upper trangular Cholesky factor of the covariance matrix $V$ .

(We have reversed the time axis in dating the $a$ ’s relative to earlier)

The time axis can be reversed in representation (62.27) by replacing $L$ with $L^{T}$ .

The optimal decision rule to use at time $0 \leq t \leq N$ is then given by the $(N - t + 1)^{t h}$ row of

\begin{array}{r} U \bar{y} = L^{- 1} {\tilde{U}}^{- 1} [\begin{array}{c} 0 & 0 \\ 0 & I_{(t + 1)} \end{array}] \tilde{U} \bar{a} + K [\begin{array}{c} y_{- 1} \\ ⋮ \\ y_{- m} \end{array}] \end{array}

62.5. Exercises #

62.5.1. Exercise 1#

Let $Y_{t} = (1 - 2 L) u_{t}$ where $u_{t}$ is a mean zero white noise with $E u_{t}^{2} = 1$ . Let

X_{t} = Y_{t} + ε_{t}

where $ε_{t}$ is a serially uncorrelated white noise with $E ε_{t}^{2} = 9$ , and $E ε_{t} u_{s} = 0$ for all $t$ and $s$ .

Find the Wold moving average representation for $X_{t}$ .

Find a formula for the $A_{1 j}$ ’s in

E {\hat{X}}_{t + 1} ∣ X_{t}, X_{t - 1}, \dots = \sum_{j = 0}^{\infty} A_{1 j} X_{t - j}

Find a formula for the $A_{2 j}$ ’s in

\hat{E} X_{t + 2} ∣ X_{t}, X_{t - 1}, \dots = \sum_{j = 0}^{\infty} A_{2 j} X_{t - j}

62.5.2. Exercise 2#

(Multivariable Prediction) Let $Y_{t}$ be an $(n \times 1)$ vector stochastic process with moving average representation

Y_{t} = D (L) U_{t}

where $D (L) = \sum_{j = 0}^{m} D_{j} L^{J}, D_{j}$ an $n \times n$ matrix, $U_{t}$ an $(n \times 1)$ vector white noise with :math: mathbb{E} U_t =0 for all $t$ , $E U_{t} U_{s}^{'} = 0$ for all $s \neq t$ , and $E U_{t} U_{t}^{'} = I$ for all $t$ .

Let $ε_{t}$ be an $n \times 1$ vector white noise with mean $0$ and contemporaneous covariance matrix $H$ , where $H$ is a positive definite matrix.

Let $X_{t} = Y_{t} + ε_{t}$ .

Define the covariograms as $C_{X} (τ) = E X_{t} X_{t - τ}^{'}, C_{Y} (τ) = E Y_{t} Y_{t - τ}^{'}, C_{Y X} (τ) = E Y_{t} X_{t - τ}^{'}$ .

Then define the matrix covariance generating function, as in (61.21), only interpret all the objects in (61.21) as matrices.

Show that the covariance generating functions are given by

\begin{array}{r} \begin{aligned} g_{y} (z) & = D (z) D (z^{- 1})^{'} \\ g_{X} (z) & = D (z) D (z^{- 1})^{'} + H \\ g_{Y X} (z) & = D (z) D (z^{- 1})^{'} \end{aligned} \end{array}

A factorization of $g_{X} (z)$ can be found (see [Roz67] or [Whi83]) of the form

D (z) D (z^{- 1})^{'} + H = C (z) C (z^{- 1})^{'}, C (z) = \sum_{j = 0}^{m} C_{j} z^{j}

where the zeros of $| C (z) |$ do not lie inside the unit circle.

A vector Wold moving average representation of $X_{t}$ is then

X_{t} = C (L) η_{t}

where $η_{t}$ is an $(n \times 1)$ vector white noise that is “fundamental” for $X_{t}$ .

That is, $X_{t} - \hat{E} [X_{t} ∣ X_{t - 1}, X_{t - 2} \dots] = C_{0} η_{t}$ .

The optimum predictor of $X_{t + j}$ is

\hat{E} [X_{t + j} ∣ X_{t}, X_{t - 1}, \dots] = {[\frac{C (L)}{L^{j}}]}_{+} η_{t}

If $C (L)$ is invertible, i.e., if the zeros of $det$ $C (z)$ lie strictly outside the unit circle, then this formula can be written

\hat{E} [X_{t + j} ∣ X_{t}, X_{t - 1}, \dots] = {[\frac{C (L)}{L^{J}}]}_{+} C (L)^{- 1} X_{t}

62. Classical Filtering With Linear Algebra#

62.1. Overview#